VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "cIni"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Option Explicit
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Objeto responsável por tratar as configurações
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' Guarda o nome do objeto
Private Const ST_MY_NAME As String = "cIni"

' API externa
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nsize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpstring As Any, ByVal lpFileName As String) As Long

' Endereço do arquivo
Private st_File As String

' Seção
Private st_Section As String


'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Propriedade do arquivo
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Property Get File() As String
    
    ' Retorna
    File = st_File
End Property

Public Property Let File(stInput As String)
    
    ' Seta
    st_File = stInput
End Property


'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Propriedade da seção
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Property Get Section() As String
    
    ' Retorna
    Section = st_Section
End Property

Public Property Let Section(stInput As String)
    
    ' Seta
    st_Section = stInput
End Property


'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Busca informação no INI
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Function ReadIni(stConfig As String, stDefault As String) As String
    Dim stBuff As String
    Dim stBuffLen As Long
    On Error Resume Next
    
    ' Inicia buff
    stBuff = String(LN_API_BUFF_SIZE, 0)
    
    ' Busca no INI
    stBuffLen = GetPrivateProfileString(st_Section, stConfig, stDefault, stBuff, LN_API_BUFF_SIZE, st_File)
    
    ' Retorna dados
    ReadIni = Mid(stBuff, 1, stBuffLen)
End Function


'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Grava informação no INI
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Public Sub WriteIni(stConfig As String, stValue As String)
    On Error Resume Next
    
    ' Salva
    WritePrivateProfileString st_Section, stConfig, stValue, st_File
End Sub